Voir les ip's De skype (Entrantes/Sortantes)

[UchiNoYama]

Bonjour un Mini tutoriel Pour vous expliquer comment voir les ip's entrantes et sortantes de skype.

Skype étant un logiciel de VOIP Les connections sont celles de vos amis avec lesquels vous discuter (vocal/écrit)

Je tiens à préciser que cette méthode n'est pas forcément "Gentille" Donc Si vous avez des problèmes apres avec les personnes je ne suis pas responsable de vos actes!

Bon c'est simple créer un ficher .bat ou .cmd puis écrivez ce code!

@echo off
title Skype IP by TheZapros For Cheat-gam3.com
set param=%~1

::When 0, it will act as an improved version of Netstat.
::When 1, it will grab Skype IP's.
set skype=1

setlocal enabledelayedexpansion

::Used to convert PID to process names.
for /f "tokens=1 delims=" %%A in ('tasklist') do call :PID %%A

echo [Programme:Skype.exe] IpLocale:Port - IPDistante:Port
echo.
for /f "tokens=1-27 delims=: " %%A in ('netstat -ano') do call :netstat %%A %%B %%C %%D %%E %%F %%G %%H %%I %%J %%K %%L %%M %%N %%O %%P %%Q %%R %%S %%T %%U
if "%param%"=="-log" exit /b
pause>nul
exit /b

:PID
   set pid_%2=%1
   exit /b

:netstat
set type=%1
set srcIP=%2
set srcPort=%3
set dstIP=%4
set dstPort=%5
set state=%6
set pid=%7
set name=!pid_%pid%!

::Filter local connections away.
if "%state%"=="" exit /b
if not "%type%"=="TCP" exit /b
if "%srcIP%"=="Local" exit /b
if "%dstIP%"=="*" exit /b
if "%srcIP%"=="%dstIP%" exit /b
if "%pid%"=="" exit /b

if "%dstPort%"=="[" (
   set state=LISTENING
   set srcPort=%dstIP%
   set pid=%9
   )
if "%dstPort%"=="[" set name=!pid_%pid%!

if "%name%"=="" set name=Unknown

::Skype filter
if "%skype%"=="1" (
if /I not "%name%"=="skype.exe" exit /b
if not "%state%"=="ESTABLISHED" exit /b
if "%dstPort%"=="443" exit /b
if "%dstPort%"=="12350" exit /b)

::Formatting \tabs
set srcPortTab=     %srcPort%
set namePidTab=[%name%:%pid%]                               
set srcIpPortTab=%srcIP%:%srcPort%                               
set dstIpPortTab=%dstIP%:%dstPort%                               
set stateTab=%state%                               
set namePidTab=%namePidTab:~0,20%
set srcIpPortTab=%srcIpPortTab:~0,21%
set dstIpPortTab=%dstIpPortTab:~0,21%
set stateTab=%stateTab:~0,12%
set srcPortTab=%srcPortTab:~-5%

if not "%state%"=="LISTENING" echo.%namePidTab% %srcIPPortTab% %dstIPPortTab% %stateTab%
if "%state%"=="LISTENING" echo.%namePidTab% Listening on: %srcPortTab%
exit /b

Voilà un merci sa serait Gentil =D

 

[Taissain]

Utile, Merci ;)

 

[UchiNoYama]

Utile, Merci ;)

Si tu as des questions, n'hésite pas

 

[Amnesia59]

hi ,

Et le fichier faut le mettre où :') ? Car le créer c'est simple , Mais Où ?!?

 

[Bwisingw]

On appelle ça un tuto :o

 

[emiz]

@Amnesia, a mon avis, il suffit juste de l'enregistrer en bat ou cmd et ensuite le lancer il et te dira l'IP, donc l'endroit n'a pas d'importance

 

[hurucefr]

Au pire tu a commview c'est simple gratuit et sa te met les ip avec qui tes en appelle message etc même les gens qui te parle sur facebook ya leur ip dessus ;)

 

[laurine13]

Sa sert a quoi ?

 

[ano441495]

Merci :)